cx-computer/case/assets/front.scad

include <ATX.scad>
include <functions.scad>
include <angle.scad>
include <addon.scad>
include <switch.scad>

include <../config/global.scad>
include <../config/front.scad>

function front_size() = [
    front_motherboard_size.x + front_padding * 2,
    front_height + front_padding * 2
];

module front_shape() {
    padding = front_padding;
    rounding = front_rounding;
    size = front_size();
    width = size.x;
    height = size.y;
    
    module corner(vector) {
        translate(vector) {
            circle(r = rounding);
        }
    }

    module base_shape() {
        hull() {
            for (count = square_vector(width, height, rounding)) {
                corner(count);
            }
        }
    }

    module mounting_cutoff() {
        move_y 
        = height / 2
        - angle_depth / 2
        + plywood_thickness / 2;

        move_x
        = width / 2
        - angle_depth / 2
        + plywood_thickness / 2;
        
        module right_cutoff() {
            translate([move_x, 0]) {
                rotate(90) {
                    angle_cutoff();
                }
            }
        }

        translate([0, move_y]) {
            angle_cutoff();
        }

        right_cutoff();

        mirror([1, 0]) {
            right_cutoff();
        }
    }

    module switch_move_cutoff() {
        move_x 
        = width / 2
        - switch_size().x / 2
        - angle_depth
        + plywood_thickness / 2
        - front_switch_margin.x;

        move_y 
        = height / 2
        - switch_size().y / 2
        - angle_depth
        + plywood_thickness / 2
        - front_switch_margin.y;
        
        translate([move_x, move_y]) {
            switch_cutoff();
        }
    }

    module addon_move_cutoff() {
        move_x 
        = -width / 2
        + addon_size().x / 2
        + angle_depth
        + front_addon_margin.x;

        move_y 
        = -height / 2
        + addon_size().y / 2
        + front_addon_margin.y;

        translate([move_x, move_y]) {
            addon_cutoff();
        }
    }

    difference() {
        base_shape();
        mounting_cutoff();
        switch_move_cutoff();

        if (front_addon) {
            addon_move_cutoff();
        }
    }
}

module front_object() {
    height = plywood_thickness;

    color("#AAEEFF") {
        render() {
            linear_extrude(height = height, center = true) {
                front_shape();
            }   
        }
    }
}