Create connector for wood.

assets/connector.scad

@@ -0,0 +1,70 @@
+include <../config/connector.scad>
+
+module connector_shape() {
+    rounding = connector_depth / 2;
+    move = connector_width - rounding * 2;
+
+    module base_shape(split = false) {
+        if (!split) {
+            hull() {
+                circle(r = rounding);
+
+                translate([move, 0]) {
+                    circle(r = rounding);
+                }
+            }
+        } else {
+            translate([-move, 0]) {
+                base_shape(split = false);
+            }
+        }
+    }
+
+    module holes(split = false) {
+        if (!split) {
+            space_y = rounding * 2 / (connector_holes_in_y + 1);
+            space_x = move / (connector_holes_in_x - 1);
+
+            for (count_y = [-rounding : space_y : rounding]) {
+                if (count_y != rounding && count_y != -rounding) {
+                    for (count_x = [0 : space_x : move]) {
+                        translate([count_x, count_y]) {
+                            circle(r = connector_hole / 2);
+                        }
+                    }
+                }
+            }
+        } else {
+            translate([-move, 0]) {
+                holes(split = false);
+            }
+        }
+    }
+
+    module final_shape(split = false) {
+        difference() {
+            base_shape(split);
+            holes(split);
+        }
+    }
+
+    render() {
+        final_shape(split = false);
+
+        if (connector_dual) {
+            final_shape(split = true);
+        }   
+
+        rotate(180 - connector_angle) {
+            final_shape(split = true);
+        }
+    }
+}
+
+module connector_object() {
+    color("#FAAFCB") {
+        linear_extrude(height = connector_thickness, center = true) {
+            connector_shape();
+        }
+    }
+}

assets/hinge.scad

@@ -0,0 +1,47 @@
+include <../config/hinge.scad>
+
+module hinge_object() {
+    module mount_shape() {
+        height = hinge_height;
+        width = hinge_screw + hinge_walls * 2;
+        
+        radius = width / 2;
+        move_y = height / 2;
+
+        module mount_base() {
+            hull() {
+                translate([0, move_y]) {
+                    circle(r = radius);
+                }
+
+                translate([0, -move_y]) {
+                    circle(r = radius);
+                }
+            }
+        }
+
+        module mount_holes() {
+            space = height / (hinge_screws_count - 1);
+
+            for (count = [-move_y : space : move_y]) {
+                translate([0, count]) {
+                    circle(r = hinge_screw / 2);
+                }
+            }
+        }
+
+        difference() {
+            mount_base();
+            mount_holes();
+        }
+    }
+    
+    module mount_object() {
+        linear_extrude(height = hinge_thickness, center = true) {
+            mount_shape();
+        }   
+    }
+
+    mount_object();
+}
+

config/connector.scad

@@ -0,0 +1,8 @@
+connector_angle = 120;
+connector_hole = 3;
+connector_holes_in_x = 5;
+connector_holes_in_y = 2;
+connector_width = 150;
+connector_depth = 40;
+connector_thickness = 3;
+connector_dual = false;

config/hinge.scad

@@ -0,0 +1,5 @@
+hinge_height = 50;
+hinge_thickness = 5;
+hinge_walls = 5;
+hinge_screw = 3;
+hinge_screws_count = 4;